[XSL-LIST Mailing List Archive Home] [By Thread] [By Date]

Re: [xsl] recursive loop in XSL stylesheet is failing

---

---

On 25/03/2010 15:38, George wrote:

Thanks.
I intend to get following output:
02/10/2010;Illness expenses:Pharmacy;Test Pharmacy, Oakland;-19.1;

There may be another parent category where "Illness expenses" belongs
to, lets say "George". Then the output should be as follows:
02/10/2010;George:Illness expenses:Pharmacy;Test Pharmacy, Oakland;-19.1;

Thanks in advance,
George

The following seems to do what you want, note there is no explicit recursion, or parameters involved, applying-templates just takes care of everything just as easily following attribute references as walking the trr via child relationships:


<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:key name="c" match="Category" use="@ID"/>
<xsl:variable name="c" select="document('Categories.xml')"/>
<xsl:template match="Entry">
<xsl:text>&#10;</xsl:text>
<xsl:value-of select="Date"/>
<xsl:apply-templates select="key('c',CategoryID,$c)"/>
<xsl:text>;</xsl:text>
<xsl:value-of select="Recipient"/>
<xsl:text>;</xsl:text>
<xsl:value-of select="Value"/>
</xsl:template>

<xsl:template match="Category">
 <xsl:apply-templates select="key('c',@ParentID,$c)"/>
 <xsl:text>;</xsl:text>
 <xsl:value-of select="en"/>
</xsl:template>

</xsl:stylesheet>

ash-3.2$ saxon9 g.xml g.xsl
<?xml version="1.0" encoding="UTF-8"?>

02/10/2010;Illness expenses;Pharmacy;Test Pharmacy, Oakland;-19.1
...

________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England
and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is
powered by MessageLabs. ________________________________________________________________________

---