[XSL-LIST Mailing List Archive Home] [By Thread] [By Date]

Re: [xsl] Translating grammars XML in others languages

---

---

Hi Paulo,

Not to comment on the question you asked, but rather than using
disable-output-escaping to create elements and attributes, you should
use xsl:element and xsl:attribute with attribute value templates in
their name attributes. Rather than:

> <xsl:template match="CURRICULO-VITAE">
>
>  <xsl:variable name="DocRegras" select="$PCntdDocRegras"/>
>
>  <!-- CURRICULO (INICIO) -->
>  <xsl:text disable-output-escaping="yes">&lt;</xsl:text>
>  <xsl:value-of select="$DocRegras/CURRICULO-VITAE/@CURRICULO-VITAE"/>
>  <xsl:text> </xsl:text>
>
>  <!-- @SISTEMA-ORIGEM-XML -->
>  <xsl:value-of select="$DocRegras/CURRICULO-VITAE/@SISTEMA-ORIGEM-XML"/>
>  <xsl:text>="</xsl:text>
>  <xsl:value-of select="@SISTEMA-ORIGEM-XML"/>
>  <xsl:text>" </xsl:text>
>
>  <!-- @DATA-ATUALIZACAO -->
>  <xsl:value-of select="$DocRegras/CURRICULO-VITAE/@DATA-ATUALIZACAO"/>
>  <xsl:text>="</xsl:text>
>  <xsl:value-of select="@DATA-ATUALIZACAO"/>
>  <xsl:text>" </xsl:text>
>
>  <!-- @HORA-ATUALIZACAO -->
>  <xsl:value-of select="$DocRegras/CURRICULO-VITAE/@HORA-ATUALIZACAO"/>
>  <xsl:text>="</xsl:text>
>  <xsl:value-of select="@HORA-ATUALIZACAO"/>
>  <xsl:text>" </xsl:text>
>
>  <xsl:text disable-output-escaping="yes">&gt;</xsl:text>
[snip]

use:

<xsl:template match="CURRICULO-VITAE">
  <xsl:variable name="DocRegras"
                select="$PCntdDocRegras/CURRICULO-VITAE" />
  <xsl:element name="{$DocRegras/@CURRICULO-VITAE}">
    <xsl:attribute name="{$DocRegras/@SISTEMA-ORIGEM-XML}">
      <xsl:value-of select="@SISTEMA-ORIGEM-XML" />
    </xsl:attribute>
    <xsl:attribute name="{$DocRegras/@DATA-ATUALIZACAO}">
      <xsl:value-of select="@DATA-ATUALIZACAO" />
    </xsl:attribute>
    <xsl:attribute name="{$DocRegras/@HORA-ATUALIZACAO}">
      <xsl:value-of select="@HORA-ATUALIZACAO" />
    </xsl:attribute>
    ...
  </xsl:element>
</xsl:template>

Cheers,

Jeni

---
Jeni Tennison
http://www.jenitennison.com/


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list

---