Oxygen XML Editor
 
[XSL-LIST Mailing List Archive Home] [By Thread] [By Date]

Re: [xsl] Filling out a table row

Subject: Re: [xsl] Filling out a table row
From: jingjun long <longjingjun@xxxxxxxxx>
Date: Wed, 04 Jul 2007 09:36:24 +0800
Hi Sam,

I also have similar requirement before. What I did is to design a template to add empty column like the following:



<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:template match="images">
<table border="3">
<xsl:for-each select="image[position() mod 5 = 1]">
<xsl:text>&#10;</xsl:text>
<tr>
<xsl:for-each select=".|following-sibling::image[position() &lt; 5]">
<td><xsl:value-of select="concat(@name,':',.)"/></td>
</xsl:for-each>
<xsl:call-template name="gen_blank_table_col">
<xsl:with-param name="col_num">
<xsl:value-of select="5 - (count(.|following-sibling::image[position() &lt; 5]))"/>
</xsl:with-param>
</xsl:call-template>
</tr>
</xsl:for-each>
<xsl:text>&#10;</xsl:text>
</table>
</xsl:template>


<!-- ======================================================================= -->
<!-- This template is used to generate blank table col. -->
<!-- ======================================================================= -->
<xsl:template name="gen_blank_table_col">
<xsl:param name="col_num"/>
<xsl:if test="$col_num > 0">
<td> - </td>
<xsl:call-template name="gen_blank_table_col">
<xsl:with-param name="col_num">
<xsl:value-of select="$col_num - 1"/>
</xsl:with-param>
</xsl:call-template>
</xsl:if>
</xsl:template>


</xsl:stylesheet>


Hope this helps.

Regards,

JingJun



Sam Carleton ei: 
I have a node set that I need to get into a table with 5 columns and
how ever many rows there needs to be.  I have the basic code working.
The problem I have is the table is not finished when the node set is
not a multiple of 5.  Here is a same dataset:

<images>
  <image name="a">1</image>
  <image name="b">2</image>
  <image name="c">3</image>
  <image name="d">4</image>
  <image name="e">5</image>
  <image name="f">6</image>
  <image name="g">7</image>
  <image name="h">8</image>
</images>

And the XSLT:

<xsl:template match="images">
<table border="3">
<xsl:for-each select="image[position() mod 5 = 1]">
<xsl:text>&#10;</xsl:text>
<tr>
<xsl:for-each select=".|following-sibling::image[position() &lt; 5]">
<td><xsl:value-of select="concat(@name,':',.)"/></td>
</xsl:for-each>
</tr>
</xsl:for-each>
<xsl:text>&#10;</xsl:text>
</table>
</xsl:template>

I would simply like to finish off the table with the correct number of
<td>&NBSP;</td>, now do I do that?

Sam

Current Thread
<- PreviousIndexNext ->
Re: [xsl] Filling out a table row, George Cristian Bina Thread [xsl] howto convert node set into 2, Sam Carleton
Re: [xsl] Filling out a table row, George Cristian Bina Date [xsl] howto convert node set into 2, Sam Carleton
Month

 
© 2002-2008 SyncRO Soft Ltd. All rights reserved. | Sitemap | Privacy Policy
This website was created & generated with <oXygen/> XML Editor