Re: [xsl] nested for-each to create a html table

>... but wanted to loop through Columns
>node as i need to get other informations like dataType,colSelected
>etc.. i will be using these to format the column.
>

Run the below stylesheet and examine the results, hope this helps.

Rudolf

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" encoding="UTF-8" indent="yes"/>
	<xsl:key name="findColumnByColName" match="/Results/Columns/Column"
use="colName"/>

	<xsl:template match="/">
		<MaybeThisIsThatWhatYouAreLookingFor>
			<xsl:apply-templates select="/Results/Rows/Row"/>
		</MaybeThisIsThatWhatYouAreLookingFor>
	</xsl:template>

	<xsl:template match="/Results/Rows/Row">
		<xsl:copy>
			<xsl:apply-templates/>
		</xsl:copy>
	</xsl:template>

	<xsl:template match="/Results/Rows/Row/*">
		<xsl:copy>
			<xsl:apply-templates select="key('findColumnByColName', name())/*"/>
		</xsl:copy>
	</xsl:template>

	<xsl:template match="/Results/Columns/Column/*">
		<xsl:attribute name="{name()}">
			<xsl:value-of select="."/>
		</xsl:attribute>
	</xsl:template>

</xsl:stylesheet>