Re: [xsl] Copying unknown attributes in XML to XML transformation?

David C. wrote:
> ] Try this, Bill:
> ] 
> ] <xsl:template match="connectionFactory">
> ]   <xsl:element name="connectionFactory">
> ]     <xsl:for-each select="@*">
> ]       <xsl:attribute name="{name(.)}"><xsl:value-of select="."/></xsl:attribute>
> ]     </xsl:for-each>
> ]    <xsl:attribute name="host"><xsl:value-of select="$host"/></xsl:attribute>
> ]    <xsl:attribute name="port"><xsl:value-of select="$port"/></xsl:attribute>
> ]   </xsl:element>
> ] </xsl:template>
>
> That works, but it is equivalent to the rather shorter
>
> <xsl:template match="connectionFactory">
>   <connectionFactory host="{$host}" port="{$port}">
>   <xsl:copy-of select="@*"/>
>  </connectionFactory>
> </xsl:template>

I think it's not quite equivalent, because of the order in which the
attributes are added. In the first, any existing 'host' or 'port'
attributes are added within the xsl:for-each, but then overridden by
the xsl:attribute instructions that add the values from the variables.
In the second, the 'host' and 'port' attributes are given values from
the variables, but then overridden by the attributes copied onto the
element.

I think the first *is* equivalent to:

  <connectionFactory>
     <xsl:copy-of select="@*" />
     <xsl:attribute name="host">
        <xsl:value-of select="$host" />
     </xsl:attribute>
     <xsl:attribute name="port">
        <xsl:value-of select="$port" />
     </xsl:attribute>
  </connectionFactory>

Cheers,

Jeni

---
Jeni Tennison
http://www.jenitennison.com/



 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list