[XSL-LIST Mailing List Archive Home] [By Thread] [By Date]

Translate hacks [was: Re: Uppercase]

---

---

Etienne Posthumus wrote:
>>  <xsl:if test=". = translate(., '.,:;','')">
> 
> Care to elucidate it a wee bit?

Sure; there's not much to it, really.  Instead of testing the string to
see if it contains any characters from the other string directly, you
use translate() to strip out any occurrences of the query-set from (a
copy of) the original string, and then compare it to the original to see
if they're the same.  If they're not, you know the string contains
characters from the translated-out set.  More complicated to describe
than use, probably.

You can extend this principle to test, for example, if a string ends
with a punctuation mark:

<?xml version='1.0'?>
<xsl:stylesheet version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:template match="/">
  <xsl:call-template name="endswithpunct">
    <xsl:with-param name="str" select="'abc.'"/></xsl:call-template>
  <xsl:call-template name="endswithpunct">
    <xsl:with-param name="str" select="'abc'"/></xsl:call-template>
</xsl:template>

<xsl:template name="endswithpunct">
 <xsl:param name="str"/>
 <xsl:value-of select="$str"/><xsl:text> does </xsl:text>
 <xsl:if
   test="string-length(translate(substring($str,string-length($str)),
                       ',.:;?!',''))
         != 0">
   <xsl:text>not </xsl:text>
 </xsl:if>
 <xsl:text>end with punctuation mark.&#xa;</xsl:text>
</xsl:template>

</xsl:stylesheet>

 Steve


 XSL-List info and archive:  http://www.mulberrytech.com/xsl/xsl-list

---